Modulation de fréquence avec rétroaction

Sources et résultat sonore :

• feedbackFM.csd
• Résultat sonore

Dans cet exemple, un oscillateur se module lui-même en fréquence par une boucle de rétroaction. Ici, la fréquence fondamentale de l'oscillateur est affectée par la modulation, ce qui produit une instabilité de la hauteur de la note jouée. L'indice de modulation des dernières notes de l'exemple est exagéré, ce qui augmente l'instabilité de la hauteur sans modifier le timbre.

         sr = 44100
         kr = 4410
      ksmps = 10
     nchnls = 1

          opcode fdbkFM, a, kk
            setksmps  1
kcps, kmod  xin
asig0       init      0
;in Frequency Modulation, modulation index depends upon modulator frequency
asig        oscili    1, kcps + kmod*kcps*asig0, 1
asig0       =         asig
            xout      asig
          endop

          instr 4
idur        = p3
iamp        = p4
icarcps     = cpspch(p5)
indxmul     = p6

kndx        adsr      0.4, 0.5, 0.1, 0.05
kmod        =         kndx * indxmul
asig        fdbkFM    icarcps, kmod
kenv        adsr      0.1, 0.2, 0.8, 0.2
            out       iamp * kenv * asig
          endin
   

Explication

Dans le cas de la rétroaction, la modulation de fréquence et la modulation de phase ne sont plus équivalentes. La dérive de la hauteur constatée dans la modulation de fréquence est due au fait qu'en général une composante continue (fréquence nulle) est produite dans le spectre du signal modulé. Lorsque le signal modulé est ajouté à la fréquence, cette composante continue produit un décalage de la fréquence. Dans la modulation de phase avec rétroaction, la composante continue du signal réinjecté n'affectant pas la fréquence, la hauteur reste stable.

Cette différence n'apparaissait pas dans le cas des modulations simples, car le signal modulant était une onde sinusoïdale qui, par définition, n'a pas de composante continue. On peut mettre en évidence cette influence de la composante continue dans la modulation en intercalant dans la boucle de rétroaction de l'exemple précédent un filtre bloqueur de composante continue.

Le schéma devient :

Les fichiers de l'exemple sont :

• feedbackFMwithDCBlocker.csd
• Résultat sonore

La dérive de la hauteur a disparu. Bien entendu, le résultat de la modulation est altéré par la présence du filtre et ne peut donc pas être comparé à celui de la modulation de phase avec rétroaction.

Conclusion

La modulation de phase permet d'utiliser des signaux quelconques comme modulante sans affecter la stabilité en hauteur. D'autre part, l'indice de modulation de la modulation de phase étant indépendant de la fréquence modulante, son interprétation comme mesure de la richesse du spectre produit sera plus homogène sur une large plage de hauteurs que dans le cas de la modulation de fréquence. Ces raisons font que la modulation de phase est souvent préférée à la modulation de fréquence lorsqu'il s'agit de simuler des instruments de musique.

Par contre, la dérive en fréquence pourra être un facteur intéressant dans un dispositif expérimental à caractère chaotique. C'est ce que nous verrons dans le prochain article.