mton

mton — Conversion d'un numéro de note MIDI en nom de note.

Description

Opcode de greffon dans emugens.

Convertit un numéro de note MIDI en nom de note, avec une précision d'un cent.

Syntaxe

Snote mton kmidi
Snote mton imidi

Exécution

kmidi / imidi -- Numéro de note MIDI.

Snote -- Nom de la note.

Exemple de noms de note :

        midi    numéro de note
        -------------------
        60      4C
        60.4    4C+40
        60.5    4C+
        60.9    4Db-10
        61      4C#
        61.5    4D-
      

Exemples

Voici un exemple de l'opcode mton. Il utilise le fichier mton-ntom.csd.

Exemple 599. Exemple de l'opcode mton.

<CsoundSynthesizer>
<CsOptions>
--nosound
</CsOptions>
<CsInstruments>

instr 1
    S4 mton ntom("7D+63")
    puts S4, 1

    S1  mton 60
    puts S1, 1

    S2 mton ftom(442)
    puts S2, 1

    S3 = mton(48.25)
    puts S3, 1

    k1 = ntom("4C")
    printk2 k1

    i2  ntom "4E"
    print i2

    S5 = mton(ntom("4G+"))
    puts S5, 1
    
    turnoff
endin

instr 2
    k1 = ntom("4Eb-31")
    printk2 k1
    i0  ntom "4C+"
    print i0
    i1 = ntom:i("4A")
    print i1    
	turnoff
endin

</CsInstruments>
<CsScore>

i 1 0 1
i 2 0 1

</CsScore>
</CsoundSynthesizer>


Voir aussi

cpsmidinn, mtof, ftom, ntom

Crédits

Par : Eduardo Moguillansky 2017

Nouveau greffon dans la version 6.11