ftprint

ftprint — Affiche le contenu d'une table de fonction (pour débogage).

Description

Opcode de greffon dans emugens.

Affiche le contenu d'une table de fonction (pour débogage). Fonctionne au taux-k, un déclencheur contrôlant quand afficher (utiliser ktrig=1, qui est la valeur par défaut, pour n'afficher qu'à l'initialisation).

Syntaxe

ftprint ifn [, ktrig, kstart, kend, kstep, inumcols ]

Initialisation

ifn -- La table à afficher.

inumcols -- Le nombre d'éléments à afficher dans une colonne (10 par défaut).

Exécution

ktrig -- La table sera affichée chaque fois que cette valeur change de 0 à un nombre positif. On peut l'utiliser avec metro pour afficher à intervalle donné. Une valeur de -1 indique d'afficher à chaque cycle-k (vaut 1 par défaut).

kstart -- La première position à afficher (0 par défaut).

kend -- La dernière postion à afficher (non incluse). (Par défaut = la longueur de la table).

kstep -- Le nombre d'élements à ignorer (1 par défaut)

Exemples

Voici un exemple de l'opcode ftprint. Il utilise le fichier ftprint.csd.

Exemple 375. Exemple de l'opcode ftprint.

<CsoundSynthesizer>
<CsOptions>
;-odac     ;;;realtime audio out

</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 64
nchnls = 2
0dbfs  = 1

; This is the example file for ftprint

/*

  ftprint

  Print the contents of an f-table
  (mostly for debuggin purposes)

  ftprint ifn, ktrig=1, kstart=0, kend=0, kstep=1, inumcols=0

  ifn: the table to print
  ktrig: table will be printed whenever this changes
         from non-positive to positive
  kstart: start index
  kend: end index (non inclusive)
  kstep: number of elements to skip
  inumcols: number of elements to print per line

  See also: printarray

*/

instr 1
  ifn   ftgentmp 0, 0, -13, -2,  0, 1, 2, 3, 4, 5, 6, 7, 8, 9, 10, 11, 12

  ; print all elements
  ftprint ifn

  ; print all elements in columns of 4 elements
  ftprint ifn, 1, 0, 0, 1, 4

  ; print only the first 5 elements
  ftprint ifn, 1, 0, 5

  turnoff
endin

</CsInstruments>

<CsScore>
i 1 0 0.01
</CsScore>

</CsoundSynthesizer>


Voir aussi

printarray, printf

Crédits

Auteur : Eduardo Moguillansky 2018

Nouveau greffon dans la version 6.12