faustdsp

faustdsp — Instancie un programme Faust.

Description

Opcode de greffon dans faustcsound.

Faustdsp instancie un programme Faust compilé avec faustcompile.

Syntaxe

ihandle faustdsp ifac

Initialisation

« ifac » -- identifiant d'un programme Faust compilé, produit par faustcompile.

« ihandle » -- identifiant d'une instance Faust DSP qui peut être utilisé pour exécuter un programme avec faustplay et pour accéder à ses contrôles avec faustctl.

Exemples

Voici un exemple de l'opcode faustdsp. Il utilise le fichier faustdsp.csd.

Exemple 270. Exemple de l'opcode faustdsp.

Voir les sections Audio en temps réel et Options de la ligne de commande pour plus d'information sur l'utilisation des options de la ligne de commande.

<CsoundSynthesizer>
<CsOptions>
-d -odac
</CsOptions>
<CsInstruments>
nchnls= 1

giph faustcompile {{
SR = 44100;
decimal(a) = a - floor(a);
freq = hslider("freq", 0, -20000, 20000, 1);
incr(fr) =  fr / float(SR);
phasor(fr,ph) =  incr(fr) : (+ : decimal) ~ _ :
+(ph) : decimal;
process = phasor(freq,0);
}}, "-vec -lv 1"

instr 1
kb1 = p5
ib faustdsp giph
faustctl ib,"freq",kb1
asig faustplay ib
out sin(2*$M_PI*asig)*p4*0dbfs
endin


</CsInstruments>
<CsScore>
i1 0 1 0.5 150
</CsScore>
</CsoundSynthesizer>


Crédits

Auteur : Victor Lazzarini, 2018